%# BEGIN BPS TAGGED BLOCK {{{
%#
%# COPYRIGHT:
%#
%# This software is Copyright (c) 1996-2025 Best Practical Solutions, LLC
%#                                          <sales@bestpractical.com>
%#
%# (Except where explicitly superseded by other copyright notices)
%#
%#
%# LICENSE:
%#
%# This work is made available to you under the terms of Version 2 of
%# the GNU General Public License. A copy of that license should have
%# been provided with this software, but in any event can be snarfed
%# from www.gnu.org.
%#
%# This work is distributed in the hope that it will be useful, but
%# WITHOUT ANY WARRANTY; without even the implied warranty of
%# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
%# General Public License for more details.
%#
%# You should have received a copy of the GNU General Public License
%# along with this program; if not, write to the Free Software
%# Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
%# 02110-1301 or visit their web page on the internet at
%# http://www.gnu.org/licenses/old-licenses/gpl-2.0.html.
%#
%#
%# CONTRIBUTION SUBMISSION POLICY:
%#
%# (The following paragraph is not intended to limit the rights granted
%# to you to modify and distribute this software under the terms of
%# the GNU General Public License and is only of importance to you if
%# you choose to contribute your changes and enhancements to the
%# community by submitting them to Best Practical Solutions, LLC.)
%#
%# By intentionally submitting any modifications, corrections or
%# derivatives to this work, or any other work intended for use with
%# Request Tracker, to Best Practical Solutions, LLC, you confirm that
%# you are the copyright holder for those contributions and you grant
%# Best Practical Solutions,  LLC a nonexclusive, worldwide, irrevocable,
%# royalty-free, perpetual, license to use, copy, create derivative
%# works based on those contributions, and sublicense and distribute
%# those contributions and any derivatives thereof.
%#
%# END BPS TAGGED BLOCK }}}
% $r->content_type('application/json; charset=utf-8');
<% JSON( \@suggestions ) |n %>
% $m->abort;
<%ARGS>
$term    => undef
$max     => undef
$op      => undef
$right   => undef
$return  => ''
$queue   => undef
$exclude => ''
</%ARGS>
<%INIT>
# Only allow certain return fields
$return = 'Name'
    unless $return =~ /^(?:id|Name)$/;

$m->abort unless defined $return
             and defined $term
             and length $term;

$m->callback( CallbackName => 'ModifyMaxResults', max => \$max );
$max //= 10;

my $articles = RT::Articles->new( $session{CurrentUser} );
$articles->SimpleSearch(
    Queue           => $queue,
    Return          => $return,
    Term            => $term,
    Max             => $max,
    $op ? ( Fields => { $return => $op } ) : (),
);
$m->callback( CallbackName => "ModifyArticlesLimit", Articles => $articles, Term => $term, ARGSRef => \%ARGS );

# Exclude articles we don't want
my @not_in = split /\s*,\s*/, $exclude;
$articles->Limit(
    FIELD           => 'id',
    VALUE           => \@not_in,
    OPERATOR        => 'NOT IN',
    ENTRYAGGREGATOR => 'AND',
    SUBCLAUSE       => 'excludeautocomplete'
) if @not_in;

my $count = $articles->CountAll;
my @suggestions;
# RT::Articles->AddRecord filters by ShowArticle right, so some DB records
# may be skipped. Keep paging until we collect max visible articles.
OUTER: while (@suggestions < $max) {
    while (my $a = $articles->Next) {
        next if $right and not $a->CurrentUserHasRight($right);
        my $value = $a->$return;
        my $suggestion = { label => $a->Name, value => $value };
        $m->callback( CallbackName => "ModifySuggestion", suggestion => $suggestion, article => $a );
        push @suggestions, $suggestion;
        last OUTER if @suggestions >= $max;
    }
    $articles->NextPage;
    last if $articles->FirstRow >= $count;
}
return @suggestions if defined wantarray;
</%INIT>
